Testing format example (no subfunctions)

TestThing.groovy

#!groovy

package tests

import support.PipelineSpockTestBase


class TestThing extends PipelineSpockTestBase {
  
    def scriptPath = 'vars/thing.groovy'
    def script     = null

    def setup() {
    
        this.script = loadScript(scriptPath)
    }
    
    def 'test thing'() {
        
        given:
        Closure mockWithStuff      = Mock()
        Closure mockLeaveWithStuff = Mock()
        Closure mockDoTheThing     = Mock()
        
        helper.registerAllowedMethod('doTheThing', [Map.class], mockDoTheThing)
        helper.registerAllowedMethod('withStuff', [Map.class], { args ->
            
            mockWithStuff(args)
            
            args.block()
            
            mockLeaveWithStuff()
        })
        
        when:
        script()
            
        then:
        1 * mockWithStuff({ mapArgs ->
            mapArgs.arg1 == "arg"
        })
        
        then:
        1 * mockDoTheThing({ mapArgs ->
            mapArgs.foo == "foo" &&
            mapArgs.bar == "bar"
        })
        
        then:
        1 * mockLeaveWithStuff()
    }
}

thing.groovy

#!groovy

def call(Map args) {
    
    withStuff arg1: "arg", block: {
        
        doTheThing foo: "foo", bar: "bar"
    }
}