Worker.gf

abstract Worker = Numeral -- We extend the Numeral abstract syntax to get Digits
  ** {
  flags startcat = Clause ;
cat
  Kind ;
  Clause ;

  -- The categories Int, Float and String are present in all grammars

  -- The categories Dig and Digits come from Numeral.
fun
  NItemsLiteral : Int -> Kind -> Clause ;
  NItemsDig : Digits -> Kind -> Clause ;
  Car : Kind ;

} ;

WorkerI.gf

incomplete concrete WorkerI of Worker =
-- 1) Modules that your grammar /inherits/
  Numeral -- this is still the abstract version in a functor!

-- 2) Modules that your grammar /opens/
 ** open
  Syntax,   -- for CN, S, mkS, mkCl, mkNP, mkCN, mkDet, aPl_Det
  Symbolic, -- for symb, mkSymb
  Lexicon   -- for car_N

in {

  -- Marking here explicitly where the imports come from; not needed in reality
  lincat
    Kind = Syntax.CN ;
    Clause = Syntax.S ;

lin

  -- Hacky, and produces "1 cars"
  NItemsLiteral int kind =
    let sym : Symb = Symbolic.mkSymb int.s ; -- mkSymb : Str -> Symb ;
        card : Card = Symbolic.symb sym ;    -- symb : Symb -> Card ;
        det : Det = Syntax.mkDet card ;
     in Syntax.mkS (Syntax.mkCl (Syntax.mkNP det kind)) ;

   -- Comes from the RGL, produces "1 car"
  NItemsDig num kind = Syntax.mkS (Syntax.mkCl (Syntax.mkNP (Syntax.mkDet num) kind)) ;

  Car = mkCN Lexicon.car_N ;
}

WorkerIta.gf

concrete WorkerIta of Worker =
-- 1) Modules that your grammar /inherits/
  NumeralIta -- finally we can instantiate this into a concrete syntax!
 **
  WorkerI -- this giveas us all the definitions from the functor,
          -- with the opened modules instantiated as those below

-- 2) Modules that your grammar /opens/
  with
  (Syntax = SyntaxIta),
  (Lexicon = LexiconIta),
  (Symbolic = SymbolicIta) ;