Head Skuller (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Head Skuller
author David Skinner
homepage www.puzzlescript.net
verbose_logging
debug

========
OBJECTS
========

Background
black black
11111
01111
11101
11111
10111

Target
darkblue
.....
.000.
.0.0.
.000.
.....

Wall
darkbrown darkbrown
00010
11111
01000
11111
00010

Player
red red red red
.000.
.111.
22222
.333.
.3.3.

head_front
yellow white lightbrown brown red
.....
01010
00000
04440
.000.


head_back
yellow white pink brown
.....
33333
03330
00000
.000.

skull_front
white #dddddd darkgray black
.000.
03030
00200
.000.
.111.

skull_back
white lightgray darkgray black
.000.
00000
00000
.111.
.222.

skull_head_front
yellow white lightbrown brown red lightgray
.555.
01010
00000
04440
.000.

skull_head_back
yellow lightgray pink brown
.111.
33333
03330
00000
.000.

=======
LEGEND
=======

. = Background
# = Wall
P = Player
* = skull_front
, = skull_back

@ = skull_head_front
O = head_front
Q = head_back

skull = skull_front or skull_back
head = head_front or head_back
skull_head = skull_head_front or skull_head_back

pushable = skull or head or skull_head
obstacle = pushable or wall or Player

=======
SOUNDS
=======

pushable move 36772507

================
COLLISIONLAYERS
================

Background
Target
Player, Wall, skull, head, skull_head

======
RULES
======

[ > Player | pushable ] -> [ > Player | > pushable ] 
horizontal [ > pushable | pushable ] -> [ > pushable | > pushable ]

horizontal [ > skull_front | no obstacle ] -> [ | skull_back ]
+ horizontal [ > skull_back | no obstacle ] -> [ | skull_front ]
+ horizontal [ > head_front | no obstacle ] -> [ | head_back ]
+ horizontal [ > head_back | no obstacle ] -> [ | head_front ]
+ horizontal [ > skull_head_front | no obstacle ] -> [ | skull_head_back ]
+ horizontal [ > skull_head_back | no obstacle ] -> [ | skull_head_front ]



[ > Player | pushable ] -> [ > Player | > pushable ] 
[ > pushable | pushable ] -> [ > pushable | > pushable ]

down [ > skull_front | head_front ] -> [ | skull_head_front ]
down [ > skull_back | head_back ] -> [ | skull_head_back ]

down [ skull_front | < head_front ] -> [ skull_head_front |  ]
down [ skull_back | < head_back ] -> [ skull_head_back |  ]

==============
WINCONDITIONS
==============

no skull

=======
LEVELS
=======


..#####..
###...###
#.....*.#
#.#..#*.#
#.o.o#p.#
#########



message level 1 of 10

####..
#**#..
#..###
#pq..#
#..O.#
#..###
####..

message level 2 of 10

######
#....#
#.#P.#
#.*@.#
#.O@.#
#....#
######

message level 3 of 10



message level 4 of 10

########
#......#
#.O@@,P#
#......#
#####..#
....####

message level 5 of 10

.#######
.#.....#
.#.O*O.#
##.*P*.#
#..O*O.#
#......#
########

message level 6 of 10

######.#####
#....###...#
#.**.....#P#
#.*.#OOO...#
#...########
#####.......

message level 7 of 10

#######
#.....#
#.O*O.#
#.*O*.#
#.O*O.#
#.*O*.#
#..P..#
#######

message level 8 of 10

..######
..#.**P#
..#.oo.#
..##.###
...#.#..
...#.#..
####.#..
#....##.
#.#...#.
#...#.#.
###...#.
..#####.

message level 9 of 10

#####.
#O..##
#P**.#
##...#
.##..#
..##Q#
...###

message level 10 of 10

......#####
......#O..#
......#O#.#
#######O#.#
#.P.*.*.*.#
#.#.#.#.###
#.......#..
#########..

message congratulations!