Simple Block Pushing Game (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Simple Block Pushing Game
author David Skinner
homepage www.puzzlescript.net

noaction

========
OBJECTS
========

Background
lightgreen green
11111
01111
11101
11111
10111

Target
darkblue
.....
.000.
.0.0.
.000.
.....

Wall
brown darkbrown
00010
11111
01000
11111
00010

Player
black orange white blue
.000.
.111.
22222
.333.
.3.3.

Crate
orange
00000
0...0
0...0
0...0
00000

push_u
transparent

push_d
transparent

push_l
transparent

push_r
transparent

nopush
transparent

=======
LEGEND
=======

. = Background
# = Wall
P = Player
* = Crate
@ = Crate and Target
O = Target

obstacle = crate or wall 
push = push_u or push_d or push_l or push_r
push_dlr = push_d or push_l or push_r
push_ulr = push_u or push_l or push_r
push_udr = push_u or push_d or push_r
push_udl = push_u or push_d or push_l 

SOUNDS
=======

Crate move 36772507

================
COLLISIONLAYERS
================

Background
Target
Player, Wall, Crate
push_u
push_d
push_l
push_r
nopush

======
RULES
======

[ player push_u ] -> [ up player up nopush ]
[ player push_d ] -> [ down player down nopush ]
[ player push_l ] -> [ left player left nopush ]
[ player push_r ] -> [ right player right nopush ]

[ > Player | Crate ] -> [ > Player | > Crate ] 


late [ push ] -> [ ]

late up [ player no nopush | crate | no obstacle ] -> [ player push_u | crate | ]
late down [ player no nopush | crate | no obstacle ] -> [ player push_d | crate | ]
late left [ player no nopush | crate | no obstacle ] -> [ player push_l | crate | ]
late right [ player no nopush | crate | no obstacle ] -> [ player push_r | crate | ]

late [ push_u push_dlr ] -> [ ]
late [ push_d push_ulr ] -> [ ]
late [ push_l push_udr ] -> [ ]
late [ push_r push_udl ] -> [ ]

late [ push ] -> again
late [ nopush ] -> [ ]

==============
WINCONDITIONS
==============

all Target on Crate

==============
LEVELS
==============

......#####
......#O..#
......#O#.#
#######O#.#
#.P.*.*.*.#
#.#.#.#.###
#.......#..
#########..