Flutter nix flake for android

flake.nix

{
  description = "Flutter on NixOS.";

  inputs = {
    # We disable this to use indirect nixpkgs from android-nixpkgs
    # nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    android-nixpkgs.url = "github:tadfisher/android-nixpkgs";
  };

  outputs =
    {
      flake-utils,
      nixpkgs,
      android-nixpkgs,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          config = {
            android_sdk.accept_license = true;
            allowUnfree = true;
          };
        };
        pinnedJDK = pkgs.jdk17;
        sdk = android-nixpkgs.sdk.${system} (
          sdkPkgs: with sdkPkgs; [
            build-tools-30-0-3
            build-tools-33-0-2
            build-tools-34-0-0
            platforms-android-30
            platforms-android-31
            platforms-android-34
            cmdline-tools-latest
            platform-tools
            # emulator
          ]
        );
      in
      {
        devShell = pkgs.mkShell {
          JAVA_HOME = pinnedJDK.home;
          ANDROID_HOME = "${sdk}/share/android-sdk";

          # Fix an issue with Flutter using an older version of aapt2, which does not know
          # an used parameter.
          GRADLE_OPTS = "-Dorg.gradle.project.android.aapt2FromMavenOverride=${sdk}/share/android-sdk/build-tools/34.0.0/aapt2";

          # CHROME_EXECUTABLE = "${pkgs.brave}/bin/brave";

          buildInputs = with pkgs; [
            pinnedJDK
            sdk
            flutter

            # pkgs.androidStudioPackages.stable
            # android-studio
          ];
        };
      }
    );
}

sudo adb start-server
sudo adb reconnect

adb devices
flutter doctor -v

"USB preferences" in developer settings set to "File transfer(MTP)" or "PTP". Otherwise we might get "Insufficient permissions for device.."