Simple babashka script with CSV, JSON, str, regex manipulation

sample_babashka_scripting.clj

#!/usr/bin/env bb

;; https://book.babashka.org
;; https://book.babashka.org/#built-in-namespaces
(ns parse-country-codes
  (:require
   [cheshire.core :as json]
   [clojure.data.csv :as csv]
   [clojure.java.io :as io]
   [clojure.string :as str]))

;; ===========================
;; Parse country triplets
;; ===========================

(def countries-raw (-> "countries.json"
                       slurp
                       json/parse-string))

(def countries (->> ["resources" "string"]
                    (get-in countries-raw)
                    (partition 3)))

(defn extract-country-info [[name code number]]
  (let [name (name "#text")
        code (code "#text")
        number (number "#text")]
    {:name name
     :code code
     :number number}))

(extract-country-info (nth countries 0))

(def triplets (map extract-country-info countries))

triplets
;; ===========================
;; Parse flags
;; ===========================

(def flags-raw (->> "country_flags.txt"
                    slurp
                    str/split-lines
                    (partition 2)))

(defn extract-flag-info [[code flag]]
  [(->> code
        (re-find #"\"(.*?)\"")
        last)
   (->> flag
        (re-find #"drawable\.(.*);")
        last)])

(extract-flag-info (nth flags-raw 0))

(def flags (into {} (map extract-flag-info flags-raw)))

(def full-final (map (fn [{code :code :as t}]
                       (assoc t :flag (flags code))) triplets))

full-final

(with-open [writer (io/writer "generated-country-flags.csv")]
  (csv/write-csv writer
                 (map vals full-final)))

to connect to cider,

bb nrepl-server 1667