ok

当Wifi热点-免回车.bat

@echo off
cd /d %~dp0
md %windir%\system32\just_test_root_qrxm_1025695453 1>nul 2>nul
if errorlevel 1 echo 请右键以管理员权限运行&echo 按任意键退出&pause>nul&exit
rd %windir%\system32\just_test_root_qrxm_1025695453 1>nul 2>nul

goto 7

:start
cls
echo 1.打开Wifi热点
echo 2.关闭Wifi热点
echo 3.关闭再打开Wifi
echo.
echo 4.启用Wifi热点功能
echo 5.禁用Wifi热点功能
echo.
echo 6.显示Wifi连接状态
echo 0.检查是否可以用作Wifi热点
echo.
choice /c x6054213 /n /t 9999 /d x /m "请选择："

goto %errorlevel%

::if errorlevel 7 goto 1
::if errorlevel 6 goto 2
::if errorlevel 5 goto 3
::if errorlevel 4 goto 4
::if errorlevel 3 goto 0
::if errorlevel 2 goto a
::if errorlevel 1 goto start
::if errorlevel 0 goto start

echo 这输入的是啥？&goto delay_2s_go_start

:8
netsh wlan stop hostednetwork
netsh wlan start hostednetwork
goto delay_2s_go_start

:7
netsh wlan start hostednetwork
goto delay_2s_go_start

:6
netsh wlan stop hostednetwork
goto delay_2s_go_start

:5
netsh wlan set hostednetwork mode=allow ssid=SendFile key=0123456789
goto delay_2s_go_start

:4
netsh wlan set hostednetwork mode=disallow
goto delay_2s_go_start

:3
netsh wlan show drivers|find "支持的承载网络"
goto delay_2s_go_start

:2
netsh wlan show hostednetwork
pause
goto start

:1
:0
goto start

:delay_2s_go_start
choice /t 2 /d y /n >nul
goto start