Created
April 17, 2021 06:34
-
-
Save isovector/7d6ceb67fa3f139aaeb8d4a4cf938bca to your computer and use it in GitHub Desktop.
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
{-# LANGUAGE BlockArguments #-} | |
{-# LANGUAGE GADTs #-} | |
{-# LANGUAGE GeneralizedNewtypeDeriving #-} | |
{-# LANGUAGE LambdaCase #-} | |
{-# LANGUAGE ScopedTypeVariables #-} | |
{-# LANGUAGE TypeApplications #-} | |
{-# LANGUAGE ViewPatterns #-} | |
module StateChart | |
( SC(SC) | |
, S(..) | |
, transition | |
, run | |
, dot | |
, dog_example | |
) where | |
import Control.Applicative (liftA2) | |
import Data.List (find) | |
newtype SC m e s = SC | |
{ lookupS :: s -> S m e s | |
} | |
data Transition e s = Transition | |
{ t_event :: e | |
, t_state :: s | |
} | |
deriving (Eq, Ord, Show) | |
transition :: e -> s -> [Transition e s] | |
transition e s = pure $ Transition e s | |
data S m e s where | |
Effect :: (Show a, Enum a, Bounded a) => String -> m a -> (a -> s) -> S m e s | |
Transitions :: [Transition e s] -> S m e s | |
Empty :: S m e s | |
pushS :: (Monad m, Eq e, Eq s) => SC m e s -> e -> s -> m s | |
pushS sc e0 s = pump sc =<< go (lookupS sc s) e0 | |
where | |
go (Effect _ ma fas) e = ma >>= pushS sc e . fas | |
go (Transitions ts) e = | |
case find ((== e) . t_event) ts of | |
Just (Transition _ s') -> pure s' | |
Nothing -> pure s | |
go Empty _ = pure s | |
pump :: (Eq s, Monad m) => SC m e s -> s -> m s | |
pump sc s = case lookupS sc s of | |
Effect _ ma fas -> ma >>= pump sc . fas | |
_ -> pure s | |
run :: (Monad m, Monad m, Eq e, Eq s) => SC m e s -> s -> [e] -> m s | |
run sc s = foldr (\e ms -> ms >>= pushS sc e) (pure s) | |
dot :: (Enum s, Bounded s, Show s, Show e) => SC m e s -> String | |
dot sc = mconcat [ "digraph statechart {", unlines $ dotSC sc, "}" ] | |
dotSC :: forall m e s. (Enum s, Bounded s, Show s, Show e) => SC m e s -> [String] | |
dotSC (SC sm) = foldMap (liftA2 dotS id sm) [minBound @s .. maxBound] | |
mkArr :: String -> String -> String -> String | |
mkArr s s' e = mconcat [ s , " -> " , s' , " [label=\"" , e , "\"];" ] | |
dotS :: forall m e s. (Show s, Show e) => s -> S m e s -> [String] | |
dotS s (Effect lbl (_ :: m a) fas) = | |
mkArr (show s) (show lbl) "" | |
: fmap (\a -> mkArr (show lbl) (show $ fas a) $ show a) | |
[minBound @a .. maxBound] | |
dotS s (Transitions ts) = | |
foldMap (\(Transition e s') -> pure $ mkArr (show s) (show s') (show e)) ts | |
dotS _ Empty = mempty | |
------------------------------------------------------------------------------ | |
data States = Idle | Loading | Resolved | Rejected | |
deriving (Eq, Ord, Show, Enum, Bounded) | |
data Event = FETCH | CANCEL | |
deriving (Eq, Ord, Show, Enum, Bounded) | |
dog_example :: SC IO Event States | |
dog_example = SC \case | |
Idle -> | |
Transitions $ mconcat | |
[ transition FETCH Loading | |
, transition CANCEL Rejected | |
] | |
Loading -> | |
Effect "Compare /tmp/test with 5" | |
(fmap (compare @Int 5 . read) $ readFile "/tmp/test") | |
\case | |
GT -> Idle | |
EQ -> Resolved | |
LT -> Rejected | |
Rejected -> Transitions $ | |
transition FETCH Loading | |
Resolved -> | |
Empty | |
Author
isovector
commented
Apr 21, 2021
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment