.zshrc

.zshrc

# 文字コード
export LANG=ja_JP.UTF-8

# Pathの設定
export PATH=${PATH}:/opt/android-sdk-linux/tools

# 補完
autoload -U compinit; compinit

# Emacsキーバインド
bindkey -e

# プロンプトの設定
autoload colors; colors
autoload -Uz vcs_info
PROMPT=$'
 %B%F{yellow}%~ %F{blue}%1v
%F{green}[%n@%m]%f%b$ '
PROMPT2="[%n]> "

## 履歴
# 履歴を保存するファイル指定
HISTFILE="$HOME/.zsh_history"

# 履歴の件数
HISTSIZE=10000
SAVEHIST=10000

# 履歴を共有する
setopt share_history

# 重複するコマンドを履歴に記録しない
setopt hist_ignore_all_dups

# 先頭にスペースを入れると履歴に記録しない
setopt hist_ignore_space

# 履歴にhistoryコマンドを記録しない
setopt hist_no_store

# 余分なスペースを削除して履歴に記録する
setopt hist_reduce_blanks

# 補完候補が複数ある時に、一覧表示
setopt auto_list

# 保管結果をできるだけ詰める
setopt list_packed

# 補完の時に大文字小文字を区別しない(但し大文字は小文字に変換しない)
zstyle ':completion:*' matcher-list 'm:{a-z}={A-Z}'

# 補完キー（Tab, Ctrl+I) を連打するだけで順に補完候補を自動で補完
setopt auto_menu

# Shift+Tabで逆順に補完
bindkey "\e[Z" reverse-menu-complete

# カッコの対応などを自動的に補完
setopt auto_param_keys

# ディレクトリ名の補完で末尾の / を自動的に付加し、次の補完に備える
setopt auto_param_slash

# 補完候補リストの日本語を正しく表示
setopt print_eight_bit

# コマンド訂正
setopt correct

# 履歴の検索
autoload history-search-end
zle -N history-beginning-search-backward-end history-search-end
zle -N history-beginning-search-forward-end history-search-end
bindkey "^P" history-beginning-search-backward-end
bindkey "^N" history-beginning-search-forward-end

# 色の設定
export LSCOLORS=gxfxxxxxcxxxxxxxxxgxgx
export LS_COLORS='di=01;36:ln=01;35:ex=01;32'
zstyle ':completion:*' list-colors 'di=01;36' 'ln=01;35' 'ex=01;32'

# エイリアスの設定
alias ls="ls -F --color"
alias la="ls -a"
alias ll="ls -l"
alias lla="ls -al"
alias cp="cp -i"
alias mv="mv -i"
alias rm="rm -i"

alias a="./a.out"

# ディレクトリ名だけでcdする
setopt auto_cd

# cdするときに自動でpushdする
setopt auto_pushd

#cdした後に自動でlsする
function chpwd() { ls }

# ^ でcd ..する
function cdup() {
    echo
    cd ..
    zle reset-prompt
}
zle -N cdup
bindkey '\^' cdup

# ビープ音をならなさない
setopt nobeep

# エディタ
export EDITOR=vi

case "${TERM}" in
# ターミナルの設定
kterm*|xterm)
    precmd() {
        # ウィンドウタイトルにユーザー名とホスト名を表示
        echo -ne "\033]0;${USER}@${HOST}\007"
    }
;;
# screen, byobuの設定
screen|screen-bce)
    preexec() {
        # タイトルにプロセス名を表示
        echo -ne "\ek#${1%% *}\e\\"
    }
    precmd() {
        # タイトルにディレクトリを名表示
        echo -ne "\ek$(basename $(pwd))\e\\"
        # リポジトリの表示
        psvar=()
        LANG=en_US.UTF-8 vcs_info
        psvar[1]=$vcs_info_msg_0_
    }
;;
esac