PKGBUILD cjs-g

_pkgname=cjs
pkgname=${_pkgname}-g
pkgver=r2301.b52a8550
pkgrel=1
pkgdesc="Javascript Bindings for Cinnamon"
arch=(i686 x86_64)
url="https://github.com/linuxmint/cjs"
license=(GPL)
depends=(gtk3 gobject-introspection-runtime js52 dbus-glib)
makedepends=(autoconf-archive gobject-introspection)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
options=(!emptydirs)
source=(${_pkgname}::git+https://github.com/linuxmint/cjs.git
build.patch)
sha256sums=('SKIP'
            '20c68f34a928bd798dc79c2ddfc44761faba2f5554ceb422e4efbce9986013c8')

pkgver() {
  cd ${srcdir}/${_pkgname}
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${srcdir}/${_pkgname}"
  patch -Np1 -i ../build.patch
  autoreconf -fi
}

build() {
  cd ${srcdir}/${_pkgname}
  ./configure --prefix=/usr \
              --libexecdir=/usr/lib \
              --disable-static

  #https://bugzilla.gnome.org/show_bug.cgi?id=656231
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd ${srcdir}/${_pkgname}
  # Needs a display
  make -k check || :
}

package() {
  cd ${srcdir}/${_pkgname}
  make DESTDIR="$pkgdir" install
}