Working out `assert_match` that I've been missing from Erlang.

assert_match.ml

open Ppxlib

exception No_match
   
let assert_match_ext =
  Extension.declare
    "ppx_assert_match.assert_match"
    Extension.Context.Expression
    Ast_pattern.(ppat __ __)
    (fun ~loc ~path:_ patt guard ->
      let open Ast_builder.Default in
      let main_case = case ~lhs:patt ~guard ~rhs:(eunit ~loc) in
      let fail_case = case
                        ~lhs:(ppat_any ~loc)
                        ~guard:(None)
                        ~rhs:([%expr failwith "No match."])
      in
      pexp_function ~loc [ main_case; fail_case ]
    )
   
let _ =
  Driver.register_transformation ~extensions:[assert_match_ext] "ppx_assert_match"

basic_example_tests.ml

open OUnit2

let test_exact _ =
  [%assert_match? ("hello", 2)] ("hello", 2)

type test_rec = { x : int; y : float }
  
let test_records _ =
  let rec_a = { x = 1; y = 2.5 } in
  [%assert_match? { x = 1; _ }] rec_a;
  [%assert_match? { x = 1; y } when y > 2.1] rec_a
  
let suite = "Simple early tests" >::: [ "Exact match" >:: test_exact
                                      ; "Record matches" >:: test_records
                                      ]

let _ = run_test_tt_main suite