Coerce an attribute from a Str to a URI object

Service.pm

package Service;

use Moo;
use Type::Utils qw( class_type );
use Types::Standard qw( Str );
use URI;

has endpoint => (
    coerce   => 1,
    default  => 'https://example.com/service',
    is       => 'ro',
    isa      => class_type('URI')->plus_constructors(Str, 'new'),
);

1;

service.t

use Test2::V0 -target => 'Service';
use URI;

subtest 'A Service class with an endpoint attribute of type URI' => sub {
    is( $CLASS->new(),
        object {
            call endpoint => object { prop blessed => match(qr/URI/) };
        },
        'should accept a Str as the default endpoint',
    );

    is( $CLASS->new( endpoint => 'https://example.com/service' ),
        object {
            call endpoint => object { prop blessed => match(qr/URI/) };
        },
        'should accept a Str as the endpoint',
    );

    is( $CLASS->new( endpoint => URI->new('https://example.com/service') ),
        object {
            call endpoint => object { prop blessed => match(qr/URI/) };
        },
        'should accept a URI object as the endpoint',
    );
};

done_testing();