Nix/NixOS ♥ Sizzy Dev Browser (https://sizzy.co/)

sizzy_default.nix

/*
Unfortunately, the Sizzy AppImage is somewhat closed source and has no permalink.
Therefore it can't be added to any package manager.

To install it with the Nix package manager follow the steps:

- mkdir sizzy && touch sizzy/default.nix
- cp Sizzy-<version>.AppImage sizzy
- echo <content of this file> > sizzy/default.nix
- nix-env -if sizzy/default.nix

-> sizzy should be on path and callable
*/

#{ appimageTools, lib }:
let
  # To be removed if committed one day to nixpkgs
  pkgs = import <nixpkgs> {};
  appimageTools = pkgs.appimageTools;
  lib = pkgs.lib;
  # END to be remove

  pname = "sizzy";
  version = "0.38.0";               # <= Adapt version to yours
  name = "${pname}-${version}";
  src = ./. + "/Sizzy-${version}.AppImage";
  appimageContents = appimageTools.extractType2 { inherit name src; };
in
appimageTools.wrapType2 {
  inherit name src;
  extraInstallCommands = ''
    mv $out/bin/${name} $out/bin/${pname}
    install -m 444 -D \
      ${appimageContents}/${pname}.desktop \
      $out/share/applications/${pname}.desktop
      substituteInPlace $out/share/applications/${pname}.desktop \
      --replace 'Exec=AppRun' 'Exec=${pname}'
    cp -r ${appimageContents}/usr/share/icons $out/share
  '';
  meta = with lib; {
    description = "The browser for Developers & Designers";
    homepage = "https://www.sizzy.co/";
    #license = with licenses; [ unfree ];
    #maintainers = with maintainers; [ ja0nz ];
    platforms = [ "x86_64-linux" ];
  };
}