multimethod.clj

(ns scrabble.backend.components.logic
  (:require [com.stuartsierra.component :as component]
            [taoensso.timbre :as log]

            [scrabble.backend.logic.logic :as logic])
  (:import [clojure.lang MultiFn]))

(defn make-dispatch-method []
  (new MultiFn "scrabble.backend.components.logic/logic-dispatch-method"
    (fn [_ {:keys [:event/type :event/version]}]
      [type version])
    :default
    #'clojure.core/global-hierarchy))

(defrecord Logic [repository dispatch-method users]
  component/Lifecycle
    (start [component]
      (let [dispatch-method (make-dispatch-method)
            handlers (seq (logic/-get-event-handlers users))]
        (doseq [[dispatch-value handler] handlers]
          (log/debug "Registering event handler for" dispatch-value)
          (.addMethod ^MultiFn dispatch-method dispatch-value handler))
        (assoc component :dispatch-method dispatch-method)))

    (stop [component]
      (dissoc component :dispatch-method))

  logic/Logic
    (-apply-event [this aggregate event]
      (dispatch-method aggregate event)))

(defn make [& [options]]
  (map->Logic {}))