Unlit-AlphaWithMask.shader

// Unlit alpha-blended shader.
// - no lighting
// - no lightmap support
// - no per-material color
// - accepts a masking texture of the scale of screen

Shader "Unlit/Transparent With Mask" {
Properties {
	_MainTex ("Base (RGB) Trans (A)", 2D) = "white" {}
	_MaskTex ("Mask Tex", 2D) = "white" {}
}

SubShader {
	Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
	LOD 100
	
	ZWrite Off
	Blend SrcAlpha OneMinusSrcAlpha 
	
	Pass {  
		CGPROGRAM
#pragma vertex vert
#pragma fragment frag

#include "UnityCG.cginc"

struct appdata_t {
	float4 vertex : POSITION;
	float2 texcoord : TEXCOORD0;
};

struct v2f {
	float4 vertex : SV_POSITION;
	half2 texcoord : TEXCOORD0;
	float4 screenpos : TEXCOORD1;
};

sampler2D _MainTex;
sampler2D _MaskTex;
float4 _MainTex_ST;

v2f vert (appdata_t v)
{
	v2f o;
	o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
	o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
	o.screenpos = o.vertex;
	return o;
}

fixed4 frag (v2f i) : SV_Target
{
	fixed4 col = tex2D(_MainTex, i.texcoord);
	// correct way to get a matching screen coord of [0, 1]
	half2 masktexcoord = 0.5 * (i.screenpos.xy / i.screenpos.w + 1.0);
	fixed4 mask = tex2D(_MaskTex, masktexcoord);
	col.a = mask.a;
	return col;
}
		ENDCG
	}
}

}