Vector2

vector2.js.coffee

class Vector2
  # A 2 coordinate vector.
  # http://en.wikipedia.org/wiki/Coordinate_vector
  # @param x The x coordinate of the vector
  # @param y The y coordinate of the vector
  constructor:(@x = 0, @y = 0) ->

  # Add 2 vectors.
  # @param vector A vector
  # @return vector
  add:(vector) -> new Vector2(@x + vector.x, @y + vector.y)

  # Substract 2 vectors.
  # @param vector A vector
  # @return vector
  sub:(vector) -> new Vector2(@x - vector.x, @y - vector.y)

  # Scale this vector.
  # @param vector A vector
  # @return vector
  scale:(factor) -> new Vector2(@x * factor, @y * factor)

  # Calculate the length of this vector.
  # @param void
  # @return vector
  length:() -> Math.sqrt(@x * @x + @y * @y)

  # Get the normalized vector.
  # @param void
  # @return vector
  normalize:() -> new Vector2(@x / @.length(), @y / @.length())

  # Get 2 vectors dot product.
  # @param vector A vector
  # @return The dot product
  dot:(vector) -> @x * vector.x + @y * vector.y

  # Get the perpendicular vector.
  # http://en.wikipedia.org/wiki/Perpendicular_vector
  # @param void
  # @return vector
  perp:() -> new  Vector2(-@y, @x)

window.Vector2 = Vector2