Generate "package-info.java" for existing Java packages for Kotlin. Adapted from http://stancalau.ro/java_package-info_generator_gradle/.

nullability.gradle

// Adapted from http://stancalau.ro/java_package-info_generator_gradle/
def generatedPackageInfoDir = "$buildDir/generated/package-info"

// Handle Android projects
if (project.plugins.hasPlugin("android")) {
    android.sourceSets.main.java.srcDirs generatedPackageInfoDir
}

// Handle Java projects
if (project.plugins.hasPlugin("java")) {
    sourceSets.main.java.srcDirs generatedPackageInfoDir
}

clean.doLast { generatePackageInfo }

task generatePackageInfo {
    doLast {
        new File(generatedPackageInfoDir).deleteDir()

        def packages = [] as Set

        new File(".").eachFileRecurse(groovy.io.FileType.FILES) {
            if (it.name.endsWith(".java")) {
                packages << ((it.text =~ "package (.+);")[0][1])
            }
        }

        packages.each {
            def dir = mkdir(generatedPackageInfoDir + "/" + it.replaceAll("\\.", "/"))
            def outputFile = new File(dir.absolutePath, "package-info.java")
            String templateOutput = applyPackageInfoTemplate(it)
            outputFile << templateOutput
        }
    }
}

def applyPackageInfoTemplate(packageName) {
    def engine = new groovy.text.SimpleTemplateEngine()
    def templateText = "@NonNull\n" +
        "package $packageName;\n" +
        "\n" +
        "import android.support.annotation.NonNull;"
    def templateParams = ["packageName": packageName]
    engine.createTemplate(templateText).make(templateParams).toString()
}