File listing using Hakyll

site.hs

{-# LANGUAGE OverloadedStrings #-}
import Control.Applicative ((<$>))
import Control.Arrow ((>>>))
import Data.Monoid (mempty)
import System.FilePath (takeBaseName)
import System.Posix (getFileStatus, fileSize)
import qualified Data.Map as M

import Hakyll

getFileSize :: String -> IO Integer
getFileSize path = fromIntegral . fileSize <$> getFileStatus path

main :: IO ()
main = hakyll $ do
    -- Actually copy the files
    match "files/*" $ do
        route idRoute
        compile copyFileCompiler

    -- Create a metadata page for each file
    metadata <- group "metadata" $
        match "files/*" $ do
            -- We use unsafeCompiler to do arbitrary IO actions
            compile $ unsafeCompiler $ \(Resource path) -> do
                size <- getFileSize path

                -- Create a page with some metadata
                let page = fromMap $ M.fromList
                        [ ("url",      path)
                        , ("filename", takeBaseName path)
                        , ("size",     show size ++ " bytes")
                        ] :: Page String

                return page

    -- Create a page listing!
    match "files.html" $ route idRoute
    create "files.html" $ constA mempty
        >>> setFieldPageList id "templates/file.html" "files" metadata
        >>> applyTemplateCompiler "templates/files.html"
        >>> relativizeUrlsCompiler

    -- Compile templates
    match "templates/*" $ compile templateCompiler