Queries for retsadak.nl

construct_verblijfsobject.rq

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix schema: <http://schema.org/>
prefix bag: <http://bag.basisregistraties.overheid.nl/def/bag#>
prefix gsp: <http://www.opengis.net/ont/geosparql#>
construct {
  $verblijfsobject a schema:Place , ?Schema_class ;
    schema:name ?place_name ;
    schema:address ?nummeraanduiding ;
    schema:containedIn ?woonplaats .
  ?nummeraanduiding a schema:PostalAddress ;
    schema:name ?address_name ;
    schema:postalCode ?nummeraanduiding_postcode ;
    schema:streetAddress ?streetAddress ;
    schema:addressLocality ?woonplaats_naam ;
    schema:addressCountry <http://dbpedia.org/resource/Netherlands> .
}
where {
  #some examples for testing
  values $verblijfsobject {
    <http://bag.basisregistraties.overheid.nl/bag/id/verblijfsobject/0003010000126063> # huisnummer and letter
    <http://bag.basisregistraties.overheid.nl/bag/id/verblijfsobject/0344010000075264> # huisnummer no letter
    <http://bag.basisregistraties.overheid.nl/bag/id/verblijfsobject/0344010000173567> # no postcode
  }
  $verblijfsobject a bag:Verblijfsobject .
  optional {
    $verblijfsobject a ?verblijfsobject_class .
    ?verblijfsobject_class rdfs:label ?verblijfsobject_class_label .
    values (?verblijfsobject_class ?Schema_class) {
      (bag:VerblijfsobjectBijeenkomstfunctie schema:CivicStructure)
      (bag:VerblijfsobjectCelfunctie schema:GovernmentBuilding)
      (bag:VerblijfsobjectGezondheidszorgfunctie schema:Hospital)
      (bag:VerblijfsobjectIndustriefunctie schema:LocalBusiness)
      (bag:VerblijfsobjectKantoorfunctie schema:LocalBusiness)
      (bag:VerblijfsobjectLogiesfunctie schema:Accommodation)
      (bag:VerblijfsobjectOnderwijsfunctie schema:CivicStructure)
      (bag:VerblijfsobjectOverigeGebruiksfunctie schema:Place)
      (bag:VerblijfsobjectSportfunctie schema:SportsActivityLocation)
      (bag:VerblijfsobjectWinkelfunctie schema:Store)
      (bag:VerblijfsobjectWoonfunctie schema:Residence)
#      (UNDEF schema:Place)
    }
  }
  ?verblijfsobject bag:hoofdadres ?nummeraanduiding ;
                   bag:identificatiecode ?verblijfsobject_identificatiecode .
  ?nummeraanduiding bag:huisnummer ?nummeraanduiding_huisnummer ;
                    bag:bijbehorendeOpenbareRuimte ?openbareruimte .
  optional { ?nummeraanduiding bag:huisletter ?nummeraanduiding_huisletter }
  optional { ?nummeraanduiding bag:postcode ?nummeraanduiding_postcode }
  ?openbareruimte bag:naamOpenbareRuimte ?openbareruimte_naam ;
      bag:bijbehorendeWoonplaats ?woonplaats .
  ?woonplaats bag:naamWoonplaats ?woonplaats_naam .
  bind (if(bound(?nummeraanduiding_huisletter), lcase(?nummeraanduiding_huisletter), "") as ?nummeraanduiding_huisletter_)
  bind (if(bound(?nummeraanduiding_postcode), concat(?nummeraanduiding_postcode, " "), "") as ?nummeraanduiding_postcode_)
  bind (concat(?openbareruimte_naam, " ", str(?nummeraanduiding_huisnummer), ?nummeraanduiding_huisletter_) as ?streetAddress)
  bind (concat(?streetAddress, ", ", ?nummeraanduiding_postcode_, ?woonplaats_naam) as ?address_name)
  bind (concat(str(?verblijfsobject_identificatiecode), " - ", str(?verblijfsobject_class_label), " op ", ?address_name) as ?place_name)
}

construct_woonplaats.rq

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix schema: <http://schema.org/>
prefix bag: <http://bag.basisregistraties.overheid.nl/def/bag#>
prefix gsp: <http://www.opengis.net/ont/geosparql#>
construct {
  $woonplaats a schema:Place , schema:City ;
    schema:name ?woonplaats_naam ;
    schema:branchCode ?woonplaats_identificatiecode ;
    schema:containedIn <http://dbpedia.org/resource/Netherlands> ;
    schema:sameAs ?sub .
}
where {
  #some examples for testing
  values $woonplaats {
    <http://bag.basisregistraties.overheid.nl/bag/id/woonplaats/3386> # Appingedam
    <http://bag.basisregistraties.overheid.nl/bag/id/woonplaats/3295> # Utrecht
  }
  $woonplaats a bag:Woonplaats ;
              bag:naamWoonplaats ?woonplaats_naam ;
              bag:identificatiecode ?woonplaats_identificatiecode .
  optional {
    service <http://dbpedia.org/sparql> {
      ?sub a <http://www.wikidata.org/entity/Q1852859> ;
        rdfs:label ?obj .
  	  filter (lang(?obj) = "nl")
    }
    filter (?woonplaats_naam = str(?obj))
  }
}