construct_parentChildren_for_births.rq

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
prefix : <http://data.cubiss.nl/genealogy/>
CONSTRUCT {
	?Child schema:parent ?Parent .
  	?Parent schema:children ?Child .
}
WHERE {
  graph <http://data.cubiss.nl/genealogy/> {
    ?Event a :Geboorte ;
         schema:attendee ?ChildRole , ?ParentRole.
    ?ChildRole schema:roleName "Kind" ;
    	schema:attendee ?Child .
    ?ParentRole schema:roleName ?ParentRoleName ;
        schema:attendee ?Parent .
    values ?ParentRoleName {"Vader" "Moeder"}
  }
}
limit 1000

construct_parentChildren_for_marriages.rq

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
prefix : <http://data.cubiss.nl/genealogy/>
CONSTRUCT {
	?Child schema:parent ?Parent .
  	?Parent schema:children ?Child .
}
WHERE {
  graph <http://data.cubiss.nl/genealogy/> {
    values ?EventType {:Trouwen :Huwelijk}
    ?Event a ?EventType ;
         schema:attendee ?ChildRole , ?ParentRole.
    ?ChildRole schema:roleName ?ChildRoleName ;
    	schema:attendee ?Child .
    ?ParentRole schema:roleName ?ParentRoleName ;
        schema:attendee ?Parent .
    values (?ChildRoleName ?ParentRoleName) {
      ("Bruid" "Vader van de bruid")
      ("Bruid" "Moeder van de bruid")
      ("Bruidegom" "Vader van de bruidegom")
      ("Bruidegom" "Moeder van de bruidegom")
    }
  }
}
limit 1000

construct_sameAs_for_births.rq

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
prefix : <http://data.cubiss.nl/genealogy/>
CONSTRUCT {
  ?Person owl:sameAs ?Person_ 
}
WHERE {
  graph <http://data.cubiss.nl/genealogy/> {
    ?Event a :Geboorte ;
         schema:startDate ?birthDate ;
         schema:attendee [
      		schema:attendee ?Person ;
      		schema:roleName "Kind" ] .
    ?Person schema:givenName ?givenName ;
            schema:familyName ?familyName .
    ?Person_ schema:givenName ?givenName ;
            schema:familyName ?familyName ;
            schema:birthDate ?birthDate .
  }
}
limit 10