promise_from_event.pl

use Mojo::Base -strict;

use Mojo::Util 'dumper';
use Mojo::Promise;
use Mojo::EventEmitter;
use Mojo::IOLoop;

sub promise_from_event {
  my ($emitter, $success, $error) = @_;
  my $p = Mojo::Promise->new;

  my %subs;
  my $cb = sub {
    my ($method, $emitter, @args) = @_;
    $emitter->unsubscribe($_ => $subs{$_}) for keys %subs;
    $p->$method(@args);
  };
  $subs{$success} = $emitter->on($success => sub { $cb->(resolve => @_) });
  $subs{$error}   = $emitter->on($error   => sub { $cb->(reject  => @_) }) if $error;

  return $p;
}

## Usage

my $bus = Mojo::EventEmitter->new;
my $p = promise_from_event($bus, 'connect', 'error');
my $diag = sub {
  say shift;
  print dumper [@_];
  print dumper [$bus->subscribers('connect'), $bus->subscribers('error')];
  Mojo::IOLoop->stop;
};

$p->then(sub{ $diag->(resolved =>  @_) }, sub { $diag->(rejected => @_) });
#Mojo::IOLoop->next_tick(sub { $bus->emit(connect => 1) });
Mojo::IOLoop->next_tick(sub { $bus->emit('error' => 'argh') });
Mojo::IOLoop->start;