defines a function looks_like_coderef which returns true if some value can behave like a coderef

coderef.pl

#!/usr/bin/env perl

use Mojo::Base -strict;

use Scalar::Util qw/reftype blessed/;
use overload ();

sub looks_like_coderef {
  my $val = shift;
  return 1 if reftype $val eq 'CODE';
  return 0 unless blessed $val;
  return !! overload::Method($val, '&{}');
}

{
  package mytest::overload;
  use Mojo::Base -base;
  use overload '&{}' => sub { return sub{} };
}

{
  package mytest::coderef;
  sub new { return bless sub{}, __PACKAGE__ }
}

use Test::More;

ok looks_like_coderef( sub{} ), 'coderef';
ok looks_like_coderef( mytest::overload->new ), 'overloading class';
ok looks_like_coderef( mytest::coderef->new  ), 'blessed coderef';

ok ! looks_like_coderef( 'hi' ), 'string';
ok ! looks_like_coderef( 1 ), 'number';
ok ! looks_like_coderef( [] ), 'arrayref';
ok ! looks_like_coderef( {} ), 'hashref';
ok ! looks_like_coderef( bless {}, 'HashrefClass'), 'non-overloading class';

done_testing;