example of a worker process communicating via websocket. not sure its the best idea

client.pl

#!/usr/bin/env perl

use Mojo::Base -strict;
use Mojo::UserAgent;
use Mojo::IOLoop;

my $ua = Mojo::UserAgent->new;
my $url = 'ws://localhost:3000/ws';

say "Connecting to $url";

my $delay = Mojo::IOLoop->delay(
  sub {
    my $delay = shift;
    $ua->websocket($url => $delay->begin);
  },
  sub {
    my ($delay, $tx) = @_;
    $tx->on( finish => sub { say 'Closed'; Mojo::IOLoop->stop } );
    $tx->send('About to do stuff', $delay->begin(0));
  },
  sub {
    # this step seems necessary to ensure that the loop isn't 
    # blocked before the message is really away
    my ($delay, $tx) = @_;
    my $end = $delay->begin(0);
    Mojo::IOLoop->timer( 0.25 => sub { $end->($tx) } );
  },
  sub {
    my ($delay, $tx) = @_;
    my $end = $delay->begin(0);
    sleep 3; # long running blocking process
    $tx->send( 'Done', sub { $end->($tx) } );
  },
  sub {
    my ($delay, $tx) = @_;
    $tx->finish;
  },
);

Mojo::IOLoop->start;

server.pl

#!/usr/bin/env perl

use Mojolicious::Lite;

websocket '/ws' => sub {
  my $c = shift;
  $c->on( message => sub {
    my ($c, $msg) = @_;
    say "Got: $msg";
  });
};

app->start;