Using Test::Mojo for purely plack apps

plugin.t

use Mojolicious::Lite;

plugin MountPSGI => {'/' => 'test.pl'};

use Test::More;
use Test::Mojo;

my $t = Test::Mojo->new;

$t->get_ok('/hello/joel')
  ->status_is(200)
  ->text_is('#name' => 'joel');

done_testing;

test.pl

#!/usr/bin/perl
use Dancer;

get '/hello/:name' => sub {
    return 'Why, hello there <span id="name">' . param('name') . '</span>';
};

dance;

test.t

use strict;
use warnings;

use Test::More;
use Test::Mojo;

{
  package Mojo::PSGIRunner;
  use Mojo::Base 'Mojo';
  use Mojolicious::Plugin::PlackMiddleware;

  has app => sub {
    require Plack::Util;
    Plack::Util::load_psgi(shift->name);
  };
  has name => sub { die 'an application name (path or class name) or instance (see app) is required' };

  sub handler {
    my ($self, $tx) = @_;
    my $req = Mojolicious::Plugin::PlackMiddleware::mojo_req_to_psgi_env($tx->req);
    my $res = $self->app->($req);
    $tx->res(Mojolicious::Plugin::PlackMiddleware::psgi_res_to_mojo_res($res));
    $tx->resume;
  }
}

my $app = Mojo::PSGIRunner->new(name => 'test.pl');
my $t = Test::Mojo->new->app($app);

$t->get_ok('/hello/joel')
  ->status_is(200)
  ->text_is('#name' => 'joel');

done_testing;