Vigenere cipher in a completely pointless (I mean, um, point-free) style

vignere.clj

;; an appropriate prelude...
(def parpar (partial partial partial))

(def parapply (parpar apply))

(def parconj (parpar conj))

;; one convenient constant
(def char-offset (int \A))

(def ^{:arglists '[[key text]]
       :doc "Enciphers plaintext using key (padding by repeating the key if
             necessary"}
  vigenere
  (comp (parapply str)
        (parapply map
                 (comp char
                       (partial + char-offset)
                       (parapply mod)
                       (parconj '(26))
                       (parapply +)
                       (partial map (comp -
                                          (partial - char-offset)
                                          int))
                       list))
        (parapply update-in)
        (parconj (list [0] cycle))
        (partial mapv (memfn toUpperCase))
        list))

(assert (= (vigenere "counton" "vigenerecipher")
           "XWARGSEGQCCASE"))