Scalpel example

scalpel-example.hs

import Text.HTML.Scalpel
import Control.Applicative ((<|>))

type Author = String

data Comment = TextComment Author String | ImageComment Author URL
  deriving Show

-- allComments :: IO (Maybe [Comment])
-- allComments = scrapeURL "http://example.com/article.html" comments

comments :: Scraper String [Comment]
comments = chroots ("div" @: [hasClass "container"]) comment

comment :: Scraper String Comment
comment = textComment <|> imageComment

textComment :: Scraper String Comment
textComment = do
  author      <- text $ "span" @: [hasClass "author"]
  commentText <- text $ "div"  @: [hasClass "text"]
  return $ TextComment author commentText

imageComment :: Scraper String Comment
imageComment = do
  author   <- text       $ "span" @: [hasClass "author"]
  imageURL <- attr "src" $ "img"  @: [hasClass "image"]
  return $ ImageComment author imageURL

main :: IO ()
main = do
  html <- readFile "article.html"
  let (Just cs) = scrapeStringLike html comments
  mapM_ (putStrLn . show) cs