A simple chrome message handler for chrome extensions

background.coffee

class BackgroundMessageHandler extends SimpleChromeMessageHandler

	onHello: (name) ->
		@send "reply", "OK, #{name}"

chrome.runtime.onConnect.addListener (port) ->
    handler = new BackgroundMessageHandler(port)

content_script.coffee

class ContentMessageHandler extends SimpleChromeMessageHandler

	onReply: (reply) ->
		console.log reply

port = chrome.runtime.connect()
handler = new ContentMessageHandler(port)
handler.send 'hello', '7lemon'

simple_chrome_message_handler.coffee

class SimpleChromeMessageHandler

    getEventName = (match, prefix, eventName) ->
        do eventName.toUpperCase

    constructor: (port) ->
        @_port = port
        port.onMessage.addListener _.bind(@_dispatch, this)
        port.onDisconnect.addListener -> console.log 'port disconnected'

    send: ->
        name = _.first(arguments)
        return false unless _.isString(name)
        @_port.postMessage name: name, data: _.tail(arguments)

    _dispatch: ({name: name, data: data}) ->
        methodName = "on#{name.replace /(^|:)(\w)/gi, getEventName}"
        method = this[methodName]
        return false unless _.isFunction(method)
        method.apply this, data