groupby.clj

(defn group-by
  "(group-by first second     [[1 3] [1 4] [2 5]]) => {1 [3 4], 2 [5]}
   (group-by first second + 0 [[1 3] [1 4] [2 5]]) => {1 7,     2 5}

   (group-by first second         [[1 [3]] [1 [4]] [2 [5]]]) => {1 [[3] [4]], 2 [[5]]}
   (group-by first second concat  [[1 [3]] [1 [4]] [2 [5]]]) => {1 (3 4), 2 (5)}
   (group-by first second into    [[1 [3]] [1 [4]] [2 [5]]]) => {1 [3 4], 2 [5]}
   (group-by first second into [] [[1 [3]] [1 [4]] [2 [5]]]) => {1 [3 4], 2 [5]}
   (group-by first second into () [[1 [3]] [1 [4]] [2 [5]]]) => {1 (4 3), 2 (5)}

   ;; as filter:
   (group-by first any? second even? conj () [[1 3] [1 4] [2 5]])      => {1 (4)}
   ;; as reducer (see index-by below):
   (group-by first any? second even? max   0 [[1 3] [1 6] [1 4] [2 5]] => {1 6})"

  ([kf coll] (clojure.core/group-by kf coll))
  ([kf vf coll] (group-by kf vf conj [] coll))
  ([kf vf rf coll] (group-by kf vf rf [] coll))
  ([kf vf rf init coll]
   (->> coll
     (reduce
       (fn [m x]
         (let [k (kf x)]
           (assoc! m k (rf (get m k init) (vf x)))))
       (transient {}))
     (persistent!)))
  ([kf kpred vf vpred rf init coll]
   (->> coll
     (reduce
       (fn [m x]
         (let [k (kf x)]
           (if-not (kpred k)
             m
             (let [v (vf x)]
               ;; no empty collections as a 'side effect':
               (if-not (vpred v)
                 m
                 (assoc! m k (rf (get m k init) v)))))))
       (transient {}))
     (persistent!))))


(defn index-by
  "(index-by first second [[1 3] [1 4] [2 5]]) => {1 4, 2 5}"
 ([kf coll]
  (reduce
    (fn [acc v] (assoc acc (kf v) v))
    {} coll))
 ([kf vf coll]
  (reduce
    (fn [acc v] (assoc acc (kf v) (vf v)))
    {} coll))
 ([kf kpred vf vpred coll]
  (group-by kf kpred vf vpred right nil coll))
 ([kf kpred vf vpred default coll]
  (group-by kf kpred vf vpred right default coll)))

(def inp [[#:outnordic.article{:number "PL11051"} #:outnordic.product{:number "FS151670"}]
          [#:outnordic.article{:number "A061157"} #:outnordic.product{:number "FS147898"}]])

(group-by #(-> % first :outnordic.article/number) #(-> % second :outnordic.product/number) inp)

{"PL11051" ["FS151670"], "A061157" ["FS147898"]}