AngularJS filter of Drupal's truncate_utf8() function

helpers.coffee

  app.filter "truncateText", ->
    (string, maxLength, wordsafe = false, addEllipsis = false, minWordsafeLength = 1) ->
      ellipsis = ''
      maxLength = Math.max(maxLength, 0)
      minWordsafeLength = Math.max(minWordsafeLength, 0)

      # Remove HTML tags
      string = string.replace(/<(?:.|\n)*?>/gm, '')

      # No truncation needed, so don't add ellipsis, just return.
      return string if (string.length <= maxLength)

      if (addEllipsis)
        # Truncate ellipsis in case max_length is small.
        ellipsis = "...".substr(0, maxLength)
        maxLength -= ellipsis.length
        maxLength = Math.max(maxLength, 0)

      # Do not attempt word-safe if lengths are bad.
      wordsafe = false if (maxLength <= minWordsafeLength)

      if (wordsafe)
        # Find the last word boundary, if there is one within minWordsafeLength
        # to maxLength characters
        re = new RegExp('^(.{' + minWordsafeLength + ',' + maxLength + '})')
        match = string.match(re)
        string = if match[1] then match[1] else string.substr(0, maxLength)
      else
        string = string.substr(0, maxLength)

      string += ellipsis if addEllipsis

      return string