Zeroes out all tip joints' orients axis.

orientTipJointsToParent.mel

// Orient tip joint to parent
{
    proc string[] getChildren(string $nodes[])
    {
        return `listRelatives -f -c $nodes`;
    }

    proc int isTip(string $node)
    {
        if (size(getChildren({$node})) > 0)
            return 0;
        else
            return 1;
    }


    proc orientTipJointsToParent(string $nodes[])
    {
        for($obj in $nodes)
        {
            string $tips[];
            
            // find tip joint
            string $children[] = getChildren({$obj});
            if(size($children) == 0)
                $tips[0] = $obj;

            while(size($children) > 0) 
            {
                for($child in $children)
                {
                    if(isTip($child) == 1)
                        $tips[size($tips)] = $child;
                }
                $children = getChildren($children);
            }

            for ($tip in $tips)
            {
                setAttr ($tip + ".jointOrientX") 0;
                setAttr ($tip + ".jointOrientY") 0;
                setAttr ($tip + ".jointOrientZ") 0;
            }

            select -r $tips;
        }
    }

    string $selection[] = `ls -sl -type joint`;

    orientTipJointsToParent($selection);
}