Rigid reatime (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

Title rigid realtime
run_rules_on_level_start
realtime_interval 0.01
key_repeat_interval 0.01

========
OBJECTS
========

background .
black darkblue
00000
00000
00100
00000
00000
control x
yellow
player p
transparent
tick '
red
goD
transparent
goL
transparent
goR
transparent
goU
transparent
act
transparent
wait64 w64
transparent
wait32 w32
transparent
wait16 w16
transparent
wait8 w8
transparent
wait4 w4
transparent
wait2 w2
transparent
wait1 w1
transparent
CD
transparent
playercharacter pc @
green
.....
.000.
.000.
.000.
.....

=======
LEGEND
=======

s = control and tick and player
w = w1 or w2 or w4 or w8 or w16 or w32
go = GoU or GoD or GoL or GoR
gov = GoU or GoD
goh = GoL or GoR

=======
SOUNDS
=======

sfx1 48897906 ( move )
sfx2 39558306 (action)

================
COLLISIONLAYERS
================

w1
w2
w4
w8
w16
w32
w64
cd
tick
control
act
go

background
player
pc

======
RULES
======

( Ticks and movement instructions )
[ x ] -> [ x ']
[ left   player ][ x ' ] -> [ player ][ x goL no ']
[ right  player ][ x ' ] -> [ player ][ x goR no ']
[ up     player ][ x ' ] -> [ player ][ x goU no ']
[ down   player ][ x ' ] -> [ player ][ x goD no ']
[ action player ][ x ' ] -> [ player ][ x act no ']

( PC moves )
['][ x no w goL ][ pc ] -> ['][ x w4 w2 ][ left  pc ] sfx1
['][ x no w goR ][ pc ] -> ['][ x w4 w2 ][ right pc ] sfx1
['][ x no w goU ][ pc ] -> ['][ x w4 w2 ][ up    pc ] sfx1
['][ x no w goD ][ pc ] -> ['][ x w4 w2 ][ down  pc ] sfx1
['][ x no w act ][ pc ] -> ['][ x w8    ][       pc ] sfx2

( Removing go markers ) 
late [' Go ] -> [']
late [' Act ] -> [']

( Waiting )
late ['][ W ] -> ['][ W CD ]
late ['][ W1 CD ] -> ['][ ]
late ['][ W2 CD no W1 ] -> ['][ W1 ]
late ['][ W4 CD no W2 no W1 ] -> ['][ W2 W1 ]
late ['][ W8 CD no W4 no W2 no W1 ] -> ['][ W4 W2 W1 ]
late ['][ W16 CD no W8 no W4 no W2 no W1 ] -> ['][ W8 W4 W2 W1  ]
late ['][ W32 CD no W16 no W8 no W4 no W2 no W1 ] -> ['][ W16 W8 W4 W2 W1 ]
late ['][ W64 CD no W32 no W16 no W8 no W4 no W2 no W1 ] -> ['][ W32 W16 W8 W4 W2 W1 ]

==============
WINCONDITIONS
==============

=======
LEVELS
=======
s........
.........
.........
.........
....@....
.........
.........
.........
.........