Valley Raid

PS:Raid

Title Valley Raid
realtime_interval 0.06
key_repeat_interval 0.06
throttle_movement
noundo

========
OBJECTS
========
Player P
transparent
GoU
transparent
GoD
transparent
GoL
transparent
GoR
transparent
Act
transparent


W32
transparent
W16
transparent
W8
transparent
W4
transparent
W2
transparent
W1
transparent
CD
transparent

Background .
darkbrown

WallL
brown
WallR
brown

NewL
red
NewR
red

EdgeL L
lightbrown brown darkbrown
11022
11102
11022
11102
11022

EdgeR R
lightbrown darkbrown brown
11102
11022
11102
11022
11102

Border #
green

Bottom _
transparent

Top -
blue

ShipN S
orange darkgrey lightgrey brown
..0..
.020.
.000.
00100
31213

ShipL
orange darkgrey lightgrey brown
..0..
.020.
.0003
00130
0121.

ShipR
orange darkgrey lightgrey brown
..0..
.020.
3000.
03110
.1210

Projectile I
lightgreen
.....
..0..
..0..
..0..
.....


Zero 0
darkgrey darkgreen darkblue
.1012..
.0202
.0202.
.0202.
.1012
One 1
darkgrey darkgreen darkblue
..02.
.102.
..02.
..02.
.1012
Two 2
darkgrey darkgreen darkblue
.1012.
.0202
...12.
..12.
.0002
Three 3
darkgrey darkgreen darkblue
.1012
...02
..012
...02
.1012
Four 4
darkgrey darkgreen darkblue
...02
..102
.1202
.0001
...02
Five 5
darkgrey darkgreen darkblue
.0002
.12..
.1012
...02
.1012
Six 6
darkgrey darkgreen darkblue
.1012
.02..
.011.
.0.02
.1012
Seven 7
darkgrey darkgreen darkblue
.0002
...12
..12.
..12.
.12..
Eight 8
darkgrey darkgreen darkblue
.1012
.0202
.1012
.0202
.1012
Nine 9
darkgrey darkgreen darkblue
.1012
.0202
.2102
...02
.1012

Target
darkgrey grey lightgrey
22222
21110
21110
21110
00000

( Explosion )

Explosion1
white yellow orange red darkred black
.....
.101.
.000.
.101.
.....
Explosion2
white yellow orange red darkred black
.4334
42123
21013
32124
4333.
Explosion3
white yellow orange red darkred black
..44
.3234
42234
4323.
.44..
Explosion4
white yellow orange red darkred black
....5
5.44.
.43..
..34.
.5...


=======
LEGEND
=======

X = Border and Player
Ship = ShipN or ShipL or ShipR

Go = GoU or God or GoL or GoR or Act

W = W1 or W2 or W4 or W8 or W16 or W32

Wall = WallL or WallR
Edge = EdgeL or EdgeR
New = NewL or NewR

Explosion = Explosion1 or Explosion2 or Explosion3 or Explosion4

Terrain = Wall or Edge or Target or Explosion

Harm = Target or Explosion2 or Explosion3 or Wall or Edge

Number = 0 or 1 or 2 or 3 or 4 or 5 or 6 or 7 or 8 or 9

=======
SOUNDS
=======

(76555308 dunggg diungggg)
(45286708 distant helicopter)
(85688508 bwobab)
(90992708 computer says maybe...)
(56793908 ...or maybe not)
(87982108 OK gun)
(8969508 brrrwuum)
(8139308 giant beetle)

================
COLLISIONLAYERS
================

Background
Go
Player
Projectile
Ship
Wall
Border Edge
Target
Ship
Explosion2 Explosion3
Explosion1 Explosion4
Bottom Top
New
W1
W2
W4
W8
W16
W32
CD
Number

======
RULES
======

( Ship )


[ up     P ] -> [ up P GoU ]
[ down   P ] -> [ up P GoD ]
[ left   P ] -> [ up P GoL ]
[ right  P ] -> [ up P GoR ]
[ action P ] -> [ up P Act ]

[ stationary P no GoL no GoR ][ Ship ] -> [ P ][ ShipN ]


[ stationary P GoL ][ Ship ] -> [ P ][ left  ShipL ]
[ stationary P GoR ][ Ship ] -> [ P ][ right ShipR ]

[ stationary P Act ][ Ship ] -> [ P ][ Ship I ]

( Shooting )

[ stationary P ][ I ]     -> [ P ][ up I ]
[ stationary P ][ I Top ] -> [ P ][ Top ]

( Exploding )


[ stationary P ][ Explosion4 ] -> [ P ][  ]
[ stationary P ][ Explosion3 ] -> [ P ][ Explosion4 ]
[ stationary P ][ Explosion2 ] -> [ P ][ Explosion3 ]
[ stationary P ][ Explosion1 ] -> [ P ][ Explosion2 ]

[ I Target ] -> [ Explosion1 ]


( Valley )

( Left... )

up   [ stationary P ][ EdgeL | Top ]               -> [ P ][ EdgeL WallL | Top NewL ]
horizontal [ stationary P ][ no Newl | NewL | no NewL ]   -> [ P ][ NewL | NewL | NewL ]
     [ stationary P ][ Border NewL ] -> [ P ][ Border ]
random [ NewL no Border ][ stationary P ]   -> [ WallL EdgeL ][ P ]
left [ stationary P ][ EdgeL | EdgeL ]    -> [ P ][ EdgeL | ]
     [ stationary P ][ NewL ]                      -> [ P ][ ] 
left [ stationary P ][ WallL | no Wall no Border ] -> [ P ][ WallL | WallL ]


( ...and right )
up   [ stationary P ][ EdgeR | Top ]               -> [ P ][ EdgeR WallR | Top NewR ]
horizontal [ stationary P ][ no NewR | NewR | no NewR]   -> [ P ][ NewR | NewR | NewR ]
     [ stationary P ][ Border NewR ] -> [ P ][ Border ]
random [ NewR no Border ][ stationary P ]   -> [ WallR EdgeR ][ P ]
right [ stationary P ][ EdgeR | EdgeR ]    -> [ P ][ EdgeR | ]
      [ stationary P ][ NewR ]                      -> [ P ][ ] 
right [ stationary P ][ WallR | no Wall no Border ] -> [ P ][ WallR | WallR ]


horizontal [ stationary P ] [ WallL | | | | | | WallR ] -> [ P ][ WallL EdgeL | no Edge no Wall |no Edge no Wall |no Edge no Wall | no Edge no Wall | no Edge no Wall | WallR EdgeR ]


( Stuff appears )
random [ Top no Wall | Top no Wall | Top no Wall ][ stationary P no W ] -> [ Top | Top Target | Top ][ P W16 random W ]

( STerrain moves down )

[ stationary P ][ Terrain        ] -> [ P ][ down Terrain ]
[ stationary P ][ Terrain Bottom ] -> [ P ][ Bottom ]



( Template )
([ stationary P ] -> [ P ])


( Ships blows up )

[ stationary P ][ Harm Ship ] -> [ P ][ Harm down Explosion1 ]




( Waiting )
late [ W ] -> [ W CD ]
late [ W1 CD ] -> [ ]
late [ W2 CD no W1 ] -> [ W1 ]
late [ W4 CD no W2 no W1 ] -> [ W2 W1 ]
late [ W8 CD no W4 no W2 no W1 ] -> [ W4 W2 W1 ]
late [ W16 CD no W8 no W4 no W2 no W1 ] -> [ W8 W4 W2 W1  ]
late [ W32 CD no W16 no W8 no W4 no W2 no W1 ] -> [ W16 W8 W4 W2 W1 ]


==============
WINCONDITIONS
==============


=======
LEVELS
=======

X---------------------------#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#L.........................R#
#LL........S...............R#
#L.........................R#
#L.........................R#
#___________________________#