jkereako/cookie.coffee

## cookie.coffee
class Cookie
  # Class method
  # Return an array of cookie values
  @rawArray = ->
    if document.cookie? then document.cookie.split ';' else no

  # Class method: searches `document.cookie` for the argument `name`.
  @find = (name) ->
    # `when !!~cookie.indexOf name` means "begins with"
    parse cookie for cookie in do Cookie.rawArray when !!~cookie.indexOf name

  # Class method
  # Unescapes and parses a cookie value string into a string, number or object
  @unserializeValue = (value) ->
    unescapedValue = unescape value
    try
      JSON.parse unescapedValue
    catch
      unescapedValue

  # Class method
  # Prepares a string, number or object for saving to cookie storage
  @serializeValue = (value) ->
    escape value = switch
      when typeof value is 'string' or typeof value is 'number' then value
      when typeof value is 'object' then JSON.stringify value

  constructor: (@name, @value, expiryInDays = 0) ->
    # Ensure there is no leading or trailing whitespace
    @name = do @name.trim
    @expiry = ''
    if expiryInDays
      @expiry = @calculateExpiry expiryInDays

  # Split the cookie string into a name/value pair
  parse = (cookie) =>
    cookieName = cookie
    .split('=')[0]
    try
      cookieValue = cookie
      .split('=')[1]
    catch
      cookieValue = null

    name: cookieName
    # Unserialize the cookie string only if it exists. Otherwise, inject a
    # boolean value to indicate that no value exists.
    value: if cookieValue? then @unserializeValue cookieValue else no

  #-- Public methods
  calculateExpiry: (expiryInDays) ->
    date = new Date()
    date.setTime do date.getTime + (expiryInDays * 24 * 60 * 60 * 1000)
    @expiry = do date.toGMTString
  # Write the cookie data
  save: ->
    document.cookie = "#{escape @name}=#{Cookie.serializeValue @value}; expires=#{@expiry}; path=/"

  # Delete the cookie data
  del: ->
    document.cookie = "#{escape @name}=; expires=Thu, 01 Jan 1970 00:00:01 GMT; path=/"