gistfile1.txt

import org.apache.tools.ant.filters.ReplaceTokens

apply plugin: 'android-sdk-manager'
apply plugin: 'android'

task generateConfigFile(type: Copy) {
  // Build config file from environment variables
  // this task doesn't get executed automatically. You have to run it explicitly. (Jenkins does this)
  from 'build.config/Config.java'
  into 'iTriageLib/src/com/healthagen/iTriage'
  filter(ReplaceTokens, tokens: System.env)
}

dependencies {
    compile fileTree(dir: 'libs', include: '*.jar')
    compile project(':iTriageLib')
    compile project(':iTriageHvPhoneLib')
    compile project(':ViewPagerIndicator')
    compile project(':sdk-android-myitriage:ITriageLibMyiTriage')
    compile project(':itriage-android-nora:ITriageNoraLib')
    provided files('provided-libs/amazonmaps-1.0.2.jar')
    compile 'com.google.android.gms:play-services:5.0.+'
    compile(group: 'com.itriage.forked.appboy', name: 'android-sdk-ui', version: '1.0.1', ext: 'aar')
}

android {
    compileSdkVersion "Google Inc.:Google APIs:9"
    buildToolsVersion '19.1.0'

    lintOptions {
        abortOnError false
    }

    buildTypes {

        File signingFile = file('signing.gradle')
        if (signingFile.exists()) {
            apply from: 'signing.gradle'
            if (signingConfigs.hasProperty('release')) {
                release {
                    signingConfig signingConfigs.release
                    runProguard true
                    proguardFiles file('proguard.cfg')
                }
            }
        }
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }

        // Move the tests to tests/java, tests/res, etc...
        instrumentTest.setRoot('tests')

        // Move the build types to build-types/<type>
        // For instance, build-types/debug/java, build-types/debug/AndroidManifest.xml, ...
        // This moves them out of them default location under src/<type>/... which would
        // conflict with src/ being used by the main source set.
        // Adding new build types or product flavors should be accompanied
        // by a similar customization.
        debug.setRoot('build-types/debug')
        release.setRoot('build-types/release')
    }
}