Convert quotes from straight to curly, with XQuery

fix-straight-quotes.xq

xquery version "3.1";

(: This uses the eXist cache module to mimic xsl:accumulator approach described 
 : by Norm Walsh at https://so.nwalsh.com/2023/08/08-accumulators :)

declare function local:initiate-cache() {
    cache:destroy("quotes"), 
    cache:create("quotes", map{}), 
    cache:put("quotes", "counter", 1)
};

declare function local:process-text($text as text()) {
    if (contains($text, '"')) then
        let $fragments := analyze-string($text, '"')/*
        let $new-text :=
            for $fragment in $fragments
            return
                if ($fragment instance of element(fn:match)) then
                    let $quote := 
                        if (cache:get("quotes", "counter") mod 2 eq 1) then
                            '“' 
                        else
                            '”'
                    let $increment := cache:put("quotes", "counter", cache:get("quotes", "counter") + 1)
                    return
                        $quote
                else
                    $fragment/string()
        return
            text { string-join($new-text) }
    else
        $text
};

declare function local:iterate-through-nodes($nodes) {
    for $node in $nodes
    return
        typeswitch ($node)
            case element() return element { node-name($node) } { $node/@*, local:iterate-through-nodes($node/node()) }
            case text() return local:process-text($node)
            default return ()
};

declare function local:fix-straight-quotes($node) {
    local:initiate-cache(),
    local:iterate-through-nodes($node)
};

let $node := <p>What about "<code>markup</code>" like "this".</p>
return
    local:fix-straight-quotes($node)

straight-to-curly-quote-pairs_results.xml

<p>What about “<code>markup</code>” like “this”.</p>