puppet code to manage how the puppet agent writes windows events

puppet_agent_log.pp

# move puppet windows events out of the Application log into a new log named Puppet
if $facts['os']['family'] == 'windows' {
  registry_key { 'Application_Puppet':
    ensure => absent,
    path   => 'HKLM\SYSTEM\CurrentControlSet\Services\EventLog\Application\Puppet',
  }
  registry_key { 'Puppet_Puppet':
    ensure  => present,
    path    => 'HKLM\SYSTEM\CurrentControlSet\Services\EventLog\Puppet\Puppet',
    require => Registry_key['Application_Puppet'],
  }
  registry_value { 'EventMessageFile':
    ensure  => present,
    path    => 'HKLM\SYSTEM\CurrentControlSet\Services\EventLog\Puppet\Puppet\EventMessageFile',
    type    => string,
    data    => 'C:\Program Files\Puppet Labs\Puppet\puppet\bin\puppetres.dll',
    notify  => Exec['Force_restart_eventlog'],
    require => Registry_key['Puppet_Puppet'],
  }
  exec { 'Force_restart_eventlog':
    command     => 'Restart-Service -Name EventLog -Force',
    refreshonly => true,
    provider    => powershell,
  }
}