Use Transmit 5 to open in iTerm (instead of Terminal.app) as mentioned here https://library.panic.com/transmit5/open-in-terminal/

TransmitOpenTerminal.txt

on openTerminal(location, remoteHost, serverPort)
	
    tell application "System Events"
        -- some versions might identify as "iTerm2" instead of "iTerm"
        set isRunning to (exists (processes where name is "iTerm")) or (exists (processes where name is "iTerm2"))
    end tell

    tell application "iTerm"
        activate
        set targetTab to ""
        set sshCommand to ""

        if ((count of remoteHost) is greater than 0) then
            set cdCommand to " 'cd \"" & location & "\"; eval \"$SHELL -il\"'"
            set sshCommand to "ssh -t " & "'" & remoteHost & "'"
        else
            set cdCommand to "cd \"" & location & "\""
        end if

        if (serverPort is greater than 0) then
            set sshCommand to sshCommand & " -p " & serverPort
        end if

        set sshCommand to sshCommand & cdCommand

        set hasNoWindows to ((count of windows) is 0)
        if isRunning and hasNoWindows then
            create window with default profile
        end if
        select first window
        
        tell the first window
            if isRunning and hasNoWindows is false then
                create tab with default profile
            end if
            if ((count of sshCommand) is greater than 0) then
                tell current session to write text sshCommand
                
        end if

        end tell
    end tell

end openTerminal

Is there a wall to pull the User Name from transmit and put it into the Open in Terminal script? I noticed on macos Monterey it wants a username and when I use the default open in terminal script it doesn't show the User Name from transmit.