JRuby 1.6.7.2 PKGBUILD

PKGBUILD

# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: FaziBear <fazibear@gmail.com>
# Contributor: Jochen Schalanda <jochen+aur@schalanda.name>
pkgname=jruby
pkgver=1.6.7.2
pkgrel=1
pkgdesc="JRuby is 100% pure-Java implementation of the Ruby programming language."
arch=(any)
url="http://www.jruby.org"
license=(CPL GPL2 LGPL2.1 custom)
depends=(java-runtime)
options=(!strip)
source=("http://$pkgname.org.s3.amazonaws.com/downloads/$pkgver/$pkgname-bin-$pkgver.tar.gz")
md5sums=('1e520f1b5130114464e5f1950cb24774')

if false; then
makedepends=(java-environment apache-ant)
build() {
  cd "$srcdir/jruby"
  ant dist-bin
  tar -C .. -xf dist/$pkgname-bin-$pkgver.tar.gz
}
fi

package() {
  cd "$pkgdir"

  mkdir opt
  cp -r "$srcdir/jruby-$pkgver" opt/jruby

  mkdir -p usr/bin
  for _file in jirb{,_swing} jruby{,c} jgem; do
    ln -s ../../opt/jruby/bin/$_file usr/bin/$_file
  done

  mkdir -p usr/share/licenses/$pkgname
  ln -s ../../../../opt/jruby/COPYING \
    usr/share/licenses/$pkgname/COPYING
}