Mockito but for clojure

mockito.clj

(defn mix-behaviours
  [& behaviours]
  (fn [& args]
    (doseq [f (butlast behaviours)]
      (apply f args))
    (apply (last behaviours) args)))

(defn dyn-type
  [implementations]
  (let [instance (reify)
        t (type instance)]
    (doseq [[protocol implem] implementations]
      (extend t protocol implem))
    t))

(defn new-dyn-type
  [implementations]
  (clojure.lang.Reflector/invokeConstructor
   (dyn-type implementations)
   (into-array [])))

(defn mk-mock
  [mock-defs]
  (new-dyn-type (reduce-kv (fn [acc protocol behaviours]
                             (assoc acc protocol (apply merge-with mix-behaviours
                                                        behaviours)))
                           {}
                           mock-defs)))

(defprotocol A
  (do-a [this arg]))
(defprotocol B
  (do-b [this arg]))

(defn generic-capture
  [capture]
  (fn [& args] (swap! capture conj args)))

(deftest mocking
  (let [capture (atom [])
        mock (mk-mock {A [{:do-a (generic-capture capture)}
                          {:do-a (constantly "done a")}]
                       B [{:do-b #(println %2)}
                          {:do-b (constantly "done b")}]})]
    (is (= "done a" (do-a mock :arga1)))
    (is (= [[mock :arga1]] @capture))
    (is (= "done b" (do-b mock :argb)))
    (is (= [[mock :arga1]] @capture) "didn't change")
    (is (= "done a" (do-a mock :arga2)))
    (is (= [[mock :arga1] [mock :arga2]] @capture))))