install_dotnetfx40.bat

::install_dotnetfx40.bat - installs dotNetFx40_Full_x86_x64.exe
::based on install_ooo.bat by @jpswade
@ECHO OFF
:SETTINGS
SET INSTALLNAME=Microsoft .NET Framework
SET SOURCEDIR=%CD%
SET INSTALLURL=http://www.microsoft.com/en-gb/download/details.aspx?id=17718
SET INSTALLEXE=dotNetFx40_Full_x86_x64.exe

:START
TITLE %INSTALLNAME% Installer
ECHO *** %INSTALLNAME% Installer
ECHO.

:ADMINCHECK
NET SESSION >nul 2>&1
IF NOT ERRORLEVEL == 0 (
    ECHO ### ERROR: ADMINISTRATOR PRIVILEGES REQUIRED
    ECHO On Windows XP: http://support.microsoft.com/kb/305780
    ECHO On Windows 7: http://windows.microsoft.com/en-gb/windows7/how-do-i-run-an-application-once-with-a-full-administrator-access-token
    ECHO.
    ECHO Press any key to exit...
    PAUSE>NUL
    EXIT /B 1
)

:MSIEXEC
ECHO *** Check the installer...
MSIEXEC /regserver>NUL 2>&1
IF ERRORLEVEL 9009 IF NOT ERRORLEVEL 9010 (
    ECHO UNABLE TO FIND MSIEXEC && PAUSE && GOTO EOF
)

:DOWNLOAD
IF NOT EXIST "%SOURCEDIR%\%INSTALLEXE%" (
    ECHO *** ERROR: %INSTALLEXE% was not found.
    ECHO Please download %INSTALLEXE% to %SOURCEDIR% before continuing.
    START /WAIT IEXPLORE "%INSTALLURL%"
    PAUSE
)
IF NOT EXIST "%SOURCEDIR%\%INSTALLEXE%" GOTO DOWNLOAD

:INSTALL
ECHO *** Installing...
"%SOURCEDIR%\%INSTALLEXE%" /q /norestart

:END
ECHO *** Done!

:EOF