WireClip

wireClip.scad

$fn = 60;

//LED Dimensions
led_d=8; //LED Diameter
led_h=11; //LED Height
led_fh=2; //LED FLange Thickness
led_fd=9; //LED Flange Diameter
led_flt=4; // The length of the flat bit

// Wireclip module
module wireClip(){
    // Wire Clip
    translate([0,0,2.7]){
        difference(){
                rotate([0,90,0])cylinder(r=1, h=3, center=true);
                rotate([0,90,0]) cylinder(r=0.6, h=4, center=true);
                translate([0,0,2]) cube([4,0.8,4], center=true);    
        }
    }
}

// LED Module, Credit to: Acarius10 (https://www.thingiverse.com/thing:38396)
// customised for 8mm Nepoixel with flat edge.
module led(){
    rotate([0,180,90]){
        translate([0,0,led_fh])cylinder(led_h-(led_d/2)-led_fh,led_d/2,led_d/2, $fn=25);
        translate([0,0,led_h-(led_d/2)])sphere(led_d/2,  $fn=25);
            difference(){
                cylinder(led_fh,led_fd/2,led_fd/2, $fn=25);
                translate([0,(led_fd/2)+.5,1]) cube([4,led_fh,4], center=true);
            }
    }
}




// Wire Clips
translate([-30,5.5,12]) wireClip();
translate([30,5.5,12]) wireClip();
translate([-30,-5.5,12]) wireClip();
translate([30,-5.5,12]) wireClip();

// Base Plate, LEDs and Support insets
difference(){
    
     translate([0,0,7])color([1,0,0]) cube([105,15,14], center=true);
     translate([45,0,14.5])led();
     translate([-45,0,14.5])led();
     translate([20,0,5]) cube([30,17, 11], center=true);
     translate([-20,0,5]) cube([30,17, 11], center=true);
}