because...

parse.pl

#!/usr/bin/perl 
use strict;
my $requests = {};

sub strip_args {
  $_ = $_[0];
  s/\?ver=.*/\?ver=/;
  s/\?email=.*/\?email=/;
  s/\?token=.*/\?token=/;
  s/\?domain=.*/\?domain=/;
  s/\?timestamp=.*/\?timestamp=/;
  return $_;
}

while (<STDIN>) {
  next unless m@((?:HEAD|GET|POST|PUT|DELETE|OPTIONS)\s+\S+)\s+[^"]+"\s+(\d{3})@;
  my ($req, $rc) = ($1, $2);
  $requests->{$rc} = [] unless $requests->{$rc};
  push(@{$requests->{$rc}}, strip_args($req));
}

my @rcs = sort { $a <=> $b } keys %$requests;

my $totals = {};

for my $rc (@rcs) {
  my @ary = @{$requests->{$rc}};
  print "-> Response code ${rc}:\n";
  my $counts = {};
  for my $elt (@ary) {
    $totals->{all}++;
    $totals->{$rc}++;
    $counts->{$elt}++;
  }
  my @reqkeys = sort { $counts->{$b} <=> $counts->{$a} } keys %$counts;
  for my $req (@reqkeys) {
    my $count = $counts->{$req};
    printf("%8d %d %s\n", $count, $rc, $req);
  }
}

for my $rc (sort keys %$totals) {
  print "total $rc: ", $totals->{$rc}, "\n";
}