Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
エクスプローラの「送る」の中に、「圧縮フォルダー」を復活させる、及び、Zipファイルの右クリックメニューを復活させる
@echo off
rem [注意] 日本語含んでいるので、SHIFT-JIS エンコードでこのバッチファイルを作成すること。
openfiles > NUL 2>&1
if NOT %ERRORLEVEL% EQU 0 goto NotAdmin
reg add HKCR\.zip /f /ve /d "CompressedFolder" > NUL
reg add HKCR\.zip /f /v "Content Type" /t REG_SZ /d "application/x-zip-compressed" > NUL
reg add HKCR\.zip /f /v "DontCompressInPackage" /t REG_SZ /d "" > NUL
reg add HKCR\.zip /f /v "PerceivedType" /t REG_SZ /d "compressed" > NUL
reg add HKCR\.zip\OpenWithProgids /f /v "CompressedFolder" /t REG_SZ /d "" > NUL
reg add HKCR\.zip\PersistentHandler /f /ve /t REG_SZ /d "{3B224B11-9363-407e-850F-C9E1FFACD8FB}" > NUL
reg add HKCR\.zip\CompressedFolder\ShellNew /f /v "Data" /t REG_BINARY /d "504b0506000000000000000000000000000000000000" > NUL
reg add HKCR\.zip\CompressedFolder\ShellNew /f /v "ItemName" /t REG_EXPAND_SZ /d "@%%SystemRoot%%\system32\zipfldr.dll,-10194" > NUL
echo.
echo 圧縮 (zip 形式) フォルダーの右クリックメニューを修復しました。
goto END
:NotAdmin
echo.
echo このバッチファイルは管理者として実行する必要があります。
echo このバッチファイルを右クリックして、[管理者として実行] を選んで実行しなおしてください。
goto END
:END
echo.
pause
@echo off
rem [注意] 日本語含んでいるので、SHIFT-JIS エンコードでこのバッチファイルを作成すること。
echo.
set fname=Compressed (zipped) Folder.ZFSendToTarget
pushd %APPDATA%\Microsoft\Windows\SendTo
if exist "%fname%" goto EXIST
echo Zip > "%fname%"
echo エクスプローラの「送る」メニューに、「圧縮 (zip 形式) フォルダー」を復活させました。
goto END
:EXIST
echo エクスプローラの「送る」メニューには、既に「圧縮 (zip 形式) フォルダー」があるようです。
goto END
:END
popd
echo.
echo 以上、処理を完了します。
pause
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment