A gist of formwork formulas from CIRIA 108: Derivation of Concrete Pressure in Formwork

Formwork.txt

/**Temperature coefficient based on CIRIA 108 - Derivation of Concrete Pressure in Formwork
*/
Get_Temperature_Coefficient_K = LAMBDA(concrete_temp_at_placing,
    LET(
        T, concrete_temp_at_placing,
        (36 / (T + 16))^2
    )
);

/**Max design pressure of concrete in formwork based on CIRIA 108 - Derivation of Concrete Pressure in Formwork
*/
Get_Max_Design_Pressure = LAMBDA(formwork_coefficient, concrete_coefficient, concrete_density, formwork_height, pour_height, concrete_temp_at_placing, rate_concrete_rise,
    LET(
        C_1, formwork_coefficient,
        C_2, concrete_coefficient,
        D, concrete_density,
        h_formwork, formwork_height,
        h_pour, pour_height,
        T, concrete_temp_at_placing,
        R, rate_concrete_rise,
        K, Get_Temperature_Coefficient_K(T),
        IF(
            C_1 * SQRT(R) > h_formwork,
            D * h_pour,
            MIN(
                D * h_pour,
                D * (C_1 * SQRT(R) + C_2 * K * SQRT(h_formwork - C_1 * SQRT(R)))
            )
        )
    )
);

/**Rate of concrete rise uniformly based on CIRIA 108 - Derivation of Concrete Pressure in Formwork
*/
Get_Rate_of_Rise_Uniform = LAMBDA(pumping_rate, length_of_wall, thickness_of_wall,
    pumping_rate / (length_of_wall * thickness_of_wall)
);