A simple ClojureScript function for linear animation

animate.cljs

;; Function takes two numeric values, `from` and `to` you wish to animate.
;; First argument is a callback function, which is called each keyframe and the current value is passed to it.
;; There are also optional keyword arguments you can use to alter duration and number of keyframes of the animation.
;; The `then` callback can be used after the animation finishes for cleanup etc. 

(defn animate
  ([callback from to & {:keys [duration keyframes then]
                        :or {duration 1000
                             keyframes 30}}]
   (let [distance (js/Math.abs (- to from))
         delta (/ distance keyframes)
         current-frame (atom 0)
         cursor (atom from)
         shift (if (< from to) + -)
         interval (atom nil)]
     (reset! interval (js/setInterval (fn []
                                        (if (< @current-frame keyframes)
                                          (do (swap! current-frame inc)
                                              (swap! cursor shift delta)
                                              (callback (js/Math.round @cursor)))
                                          (do (js/clearInterval @interval)
                                              (when then (then)))))
                                      (/ duration keyframes))))))