Compare dates

date-compare.lisp

(defun date-compare (time-a time-b)
  "Returns the symbols <, >, or =, describing the relationship between TIME-A and TIME-B."
  (declare (type timestamp time-a time-b))
  (cond
    ((< (day-of time-a) (day-of time-b)) '<)
    ((> (day-of time-a) (day-of time-b)) '>)
    (t '=)))

(defun date= (time-a time-b)
  "Return T if date of TIME-A is equal to date of TIME-B, NIL otherwise."
  (eql (date-compare time-a time-b) '=))

(defun date> (time-a time-b)
  "Return T if date of TIME-A is greater than date of TIME-B, NIL otherwise."
  (eql (date-compare time-a time-b) '>))

(defun date< (time-a time-b)
  "Return T if date of TIME-A is less than date of TIME-B, NIL otherwise."
  (eql (date-compare time-a time-b) '<))

(defun date>= (time-a time-b)
  "Return T if date of TIME-A is greater than or equal to date of TIME-B, NIL otherwise."
  (not (null (member (date-compare time-a time-b) '(> =)))))

(defun date<= (time-a time-b)
  "Return T if date of TIME-A is less than or equal to date of TIME-B, NIL otherwise."
  (not (null (member (date-compare time-a time-b) '(< =)))))