verhell.pl

#!/usr/bin/perl

use warnings;
use strict;
use version;

my @data_sources = ( [ 'qv()'         => sub { qv( shift )           } ],
                     [ 'version->new()' => sub { version->new( shift ) } ],
                    );

my @methods = ( [ 'raw'       => sub { shift            } ],
                [ 'numify'    => sub { shift->numify    } ],
                [ 'stringify' => sub { shift->stringify } ],
               );

my $colcount = ( scalar @methods );
my $rowfmt   = sprintf "%s\n", join q{ },
    '%15s', ( "%10s" ) x $colcount;

for my $verstr ( @ARGV ) {
    my ( @data_names, @data_results );
    for my $data_source ( @data_sources ) {
        my ( $name, $data_ref ) = @$data_source;
        my $data = $data_ref->( $verstr );
        push @data_results, [ $name,
                              map {
                                  eval { $_->[ 1 ]->( $data ) } or "N/A"
                              } @methods ];
    }
    
    print "\n";
    printf $rowfmt, qq{"$verstr"}, map { $_->[0] } @methods;

    for my $row_result ( @data_results ) {
        printf $rowfmt, @$row_result;
    }
}