custom fact with defined type

serial.pp

# Configure a serial port for IPMI (which provides virtual ones).
# Depends on the "serial_ports" custom fact, included in this module
define ipmi::serial {
  include stdlib
  include ipmi::serial_prerequisites

  $port_exists = member($::serial_ports, "/dev/${title}")

  if $port_exists {
    service { $title:
      ensure  => running,
      require => File["/etc/init/${title}.conf"],
    }

    file { "/etc/init/${title}.conf":
      mode    => '0644',
      owner   => 'root',
      group   => 'root',
      content => template('ipmi/tty.conf.erb'),
      notify  => Service[$title],
    }
  } else {
    service { $title:
      ensure => stopped,
    }

    file { "/etc/init/${title}.conf":
      ensure  => absent,
      require => Service[$title],
    }
  }
}

serial_ports.rb

# return a list of the active serial ports on this host
module Serial
  def self.add_facts
    Facter.add(:serial_ports) do
      confine :kernel => 'Linux'
      setcode do
        ports = Dir.glob('/dev/ttyS*').join(' ')
        setserial = '/bin/setserial'
        get_active_ports = "#{setserial} -g #{ports} |sed '/unknown/d;s/,.*//'"
        Facter::Core::Execution.exec(get_active_ports).split
      end
    end
  end
end

Serial.add_facts