list all used deprecated features

untitled

-- Listing 7.9: Which deprecated features are still in use?
DECLARE @object_name SYSNAME
SET @object_name = CASE WHEN @@servicename = 'MSSQLSERVER' THEN 'SQLServer'
                        ELSE 'MSSQL$' + @@serviceName
                   END + ':Deprecated Features'
DECLARE @PERF_COUNTER_LARGE_RAWCOUNT INT 
SELECT  @PERF_COUNTER_LARGE_RAWCOUNT = 65792

SELECT  object_name ,
        counter_name ,
        instance_name ,
        cntr_value
FROM    sys.dm_os_performance_counters
WHERE   cntr_type = @PERF_COUNTER_LARGE_RAWCOUNT
        AND object_name = @object_name
        AND cntr_value > 0

-- Listing 7.10: Returning the values of ratio PerfMon counters.
DECLARE @PERF_LARGE_RAW_FRACTION INT ,
    @PERF_LARGE_RAW_BASE INT 
SELECT  @PERF_LARGE_RAW_FRACTION = 537003264 ,
        @PERF_LARGE_RAW_BASE = 1073939712 

SELECT  dopc_fraction.object_name ,
        dopc_fraction.instance_name ,
        dopc_fraction.counter_name ,
         --when divisor is 0, return I return NULL to indicate
         --divide by 0/no values captured
        CAST(dopc_fraction.cntr_value AS FLOAT)
        / CAST(CASE dopc_base.cntr_value
                 WHEN 0 THEN NULL
                 ELSE dopc_base.cntr_value
               END AS FLOAT) AS cntr_value
FROM    sys.dm_os_performance_counters AS dopc_base
        JOIN sys.dm_os_performance_counters AS dopc_fraction
            ON dopc_base.cntr_type = @PERF_LARGE_RAW_BASE
               AND dopc_fraction.cntr_type = @PERF_LARGE_RAW_FRACTION
               AND dopc_base.object_name = dopc_fraction.object_name
               AND dopc_base.instance_name = dopc_fraction.instance_name
               AND ( REPLACE(dopc_base.counter_name,
                'base', '') = dopc_fraction.counter_name
              --Worktables From Cache has "odd" name where 
              --Ratio was left off
               OR REPLACE(dopc_base.counter_name,
               'base', '') = ( REPLACE(dopc_fraction.counter_name,
               'ratio', '') )
               )
ORDER BY dopc_fraction.object_name ,
         dopc_fraction.instance_name ,
         dopc_fraction.counter_name