When you have json that you know could be rubbish and just need a concrete parser to change how specific fields are parsed.

parse-you-a-thingy-with-imperfect-json-that-you-convert-bad-properties-from.purs

module Main where

import Prelude

import Effect (Effect)
import Effect.Console (logShow)
import Data.Either (Either)
import Foreign (ForeignError)
import Data.List.NonEmpty (NonEmptyList)
import Data.Maybe (fromMaybe)
import Data.Nullable as Nullable
import Record (modify)
import Simple.JSON (readJSON)
import Type.Prelude (SProxy(..))

type MyThingy =
  { a :: String
  , b :: Array String
  }

myThingyJsonThing1 :: String
myThingyJsonThing1 =
  """
    { "a": "hello"
    , "b": null
    }
  """

myThingyJsonThing2 :: String
myThingyJsonThing2 =
  """
    { "a": "hello"
    , "b": []
    }
  """

-- by using modify here, the type that is being parsed here uses "b" :: Nullable (Array String) from simple-json!
-- you can look at the definition of modify in purescript-record to see how the types line up!
parseMyThingyJsonFromImperfectJsonButConvertTheDirtyProperty ::
  String -> Either (NonEmptyList ForeignError) MyThingy
parseMyThingyJsonFromImperfectJsonButConvertTheDirtyProperty str =
  modify (SProxy :: SProxy "b") (fromMaybe [] <<< Nullable.toMaybe) <$> readJSON str


main :: Effect Unit
main = do
  logShow $ parseMyThingyJsonFromImperfectJsonButConvertTheDirtyProperty myThingyJsonThing1
  -- (Right { a: "hello", b: [] })
  logShow $ parseMyThingyJsonFromImperfectJsonButConvertTheDirtyProperty myThingyJsonThing2
  -- (Right { a: "hello", b: [] })